Incredible crafting macro + easy weapon crafting XP. : Star Wars Galaxies Nerfed Info

//=========================================================
//======== GENERAL CRAFT GRINDING MACRO BY tintin =========
//======== v 1.4 =========
//=========================================================
//
// Read the instructions below carefully before
// running the macro.
//
// Instructions:
//
// The macro can use up to 12 tools, all placed
// consecutively on the toolbar (one after the other)
//
// You need to create 2 ingame macros and place
// them somewhere on the toolbar for this to work.
// Do not place them between the craftingtools!
// Replace the number in the first macro with the
// number of the schematic you are using
//
// Macro 1:
// /selectDraftSchematic 01
//
// Macro 2:
// /nextCraftingStage
// /nextCraftingStage
// /createPrototype practise no item
//
//
// Now edit the configuration below and start the macro,
// You need to have the cursor visible.. no targeting
// reticule..
//
// To set a timed stop and quit (The macro will quit the
// game and stop. Useful when you are grinding afk, so that
// you will not use up resources before you have trained)
// set the configuration quit_time to a value greater than 0.
// Setting it to 0 will disable the function. Then set the
// quit command. Default is /quit, this should work for
// everyone with a standard keyboard layout, if you are
// using a swedish locale, use ~/quit.
//
// Have fun grinding afk!!
//
//=======================================================

Constructs
comps=List //Constructs the list, DONT EDIT
end

//===============================================
//============== CONFIGURATION ==================
//===============================================
constants

number_of_tools = 1 // the number of tools you are using

first_tool_x = 475 // X coordinate of first tool on toolbar
first_tool_y = 19 // Y coordinate of first tool on toolbar

first_macro = 510, 20 // coordinates of first macro on toolbar
second_macro = 540, 20 // coordinates of second macro on toolbar

close_x = 815, 63 // coordinates of the closing X on your crafting window

use_pack = 0 // do you have your comps in a pack? 1=yes 0=no
pack_coords = 330, 465 // coordinates of your pack

tool_delay = 2000 // How long to wait for the tools to open
macro_delay = 2000 // How long to wait for the ingame macro to finish
component_delay = 2000 // How long to wait after placing components

quit_time = 0 // Number of minutes until the macro quits the game and stops - 0 = off
quit_command =/quit // Quit command: /quit for american keyboard ~/quit for swedish DO NOT put a space between the command and the = sign

compensate_lag = 0 // Tries to compensate for lag by delaying more and duobleclicking twise 0=off 1=on

end

//============ COMPONENT COORDINATES ============
//
// Add the component coordinates below on the form
// ListAdd comps, componentX, componentY
//
// Add as many components as you use, just make
// sure they are visible :p

ListAdd comps, 211, 249
ListAdd comps, 211, 249
ListAdd comps, 211, 249
ListAdd comps, 211, 249

//===============================================
//============ END CONFIGURATION ================
//==== DO NOT EDIT ANYTHING BELOW THIS LINE =====
//===============================================


//========= VARIABLES DONT EDIT THESE =========
Constants
tool_x = 0
tool_y = 0
iteration = 1
iteration2 = 1
number_of_comps = 0
comp_time = 500
total_time = 0
tool_time = 0
macro_time = 0
run_time = 0
base_time = 1700
end
//============= END OF VARIABLES ==============

ListCount comps, number_of_comps

// Compute the times involved in the macro

if $compensate_lag > 0
compute $macro_delay = $macro_delay + 1000
compute $tool_delay = $tool_delay + 1000
compute $component_delay = $component_delay + 1000
end

loop $number_of_comps
compute $comp_time = $comp_time + 500
if $compensate_lag > 0
compute $comp_time = $comp_time + 500
end
end

compute $quit_time = $quit_time * 60000
compute $macro_time = $macro_delay * 2
compute $tool_time = $tool_delay * 2

if $use_pack = 1
compute $base_time = $base_time + 1000
end

compute $total_time = $base_time + $comp_time + $component_delay + $tool_time + $macro_time

// End of computation

SetActiveWindow SwgClient
delay 10000

//============== MAIN LOOP ==================

while 1=1

call check_for_stop
set tool_x = $first_tool_x
set tool_y = $first_tool_y
set $iteration = 1

delay 200

//============== LOOP TOOLS ==================

Loop $number_of_tools

if $iteration > 1
compute $tool_x = $tool_x + 32
end

if $iteration = 5
compute $tool_x = $tool_x + 32
end

if $iteration = 9
compute $tool_x = $tool_x + 32
end

//crafting tool
MousePos $tool_x,$tool_y
delay 200
LeftClick
delay $tool_delay //Wait for tool to open

//First macro
MousePos $first_macro
delay 200
LeftClick
delay $macro_delay //Wait for macro to finish
delay 500

//check for a pack
if $use_pack > 0
MousePos $pack_coords
delay 200
DoubleClick
delay 800
end


//=========== LOOP COMPONENTS ================

loop $number_of_comps
MousePos comps[$iteration2]
delay 200
DoubleClick
delay 300

if $compensate_lag > 0
delay 200
DoubleClick
delay 300
end

compute $iteration2 = $iteration2 + 1
end
set $iteration2 = 1

delay $component_delay

//second macro
MousePos $second_macro
delay 200
LeftClick
delay $macro_delay //Wait for macro to finish
delay 33000 //This is the wait for how long it will take the item to craft *********************************************

//close window
MousePos $close_x
delay 200
LeftClick
delay 200
LeftClick

delay $tool_delay //delay to open next tool

compute $iteration = $iteration + 1
compute $run_time = $run_time + $total_time
end

end

Procedure check_for_stop // check to see if we have run longer than the stop time

if $quit_time > 0
if $quit_time < $run_time
Keys $quit_command
Stop
end
end

end

Ok.. a noobs guide to mouse poses.. (Fullscreen)

take a screenshot of the game.. open the image with like a preview program.. copy the entire image..

Now.. in actool in the menu, click "tools" then click objeck mapper... if you have copied the entire image to clipboard, press the paste button.. now your picture should be displaying in the object mapper.. simply click wherever you want in the pictures and the object mapper displays the coordinates in the coordinates box..

In other cases you can use any most program to get coordinates..

simple?